IT技術互動交流平臺

SQL Server聚焦APPLY運算符(二十七)

作者:JeffckyWang  來源:IT165收集  發布日期:2016-12-19 20:32:17

前言

其實有些新的特性在SQL Server早就已經出現過,但是若非系統的去學習數據庫你會發現在實際項目中別人的SQL其實是比較復雜的,其實利用新的SQL Server語法會更加方便和簡潔,從本節開始我們將講述一些SQL Server中早已出現的新語法,簡短的內容,深入的理解,Always to reivew the basics。

初探APPLY運算符

APPLY運算符是一個非常強大的表運算符,但是APPLY不是標準的,相對應的標準叫做LATERAL,但是此標準并未在SQL Server中實現。像所有表運算符一樣,該運算符用于查詢的FROM子句中。APPLY運算符支持的類型是CROSS APPLY和OUTER APPLY。CROSS APPY僅僅實施一個邏輯查詢處理階段,而OUTER APPLY實施了兩個階段,APPLY運算符對兩個輸入表進行操作,第二個可以是一個表表達式,我們將APPLY兩側的表分別叫做左側表和右側表,右側表通常是一個派生表或TVF(內嵌表值函數)。CROSS APPLY運算符實施一個邏輯查詢處理階段-它將右側的表表達式應用到左側表的每一行,并生成一個組合結果集的結果表。CROSS APPLYl類似于交叉聯接中的CROSS JOIN,但是使用CROSS APPLY運算符,右側的表表達式可以對來自左側表的每一行表示一個不同的行集,這是與聯接的不同之處。當在右側使用一個派生表,并且派生表查詢中引用來自左側表的屬性,就可以實現此目標,或者是在右側使用一個內嵌TVF,可以傳遞左側的屬性作為輸入參數,同樣可以實現此目的-摘抄自SQL Server 2012基礎教程。下面我們看一個簡單的例子。

USE TSQL2012
GO

SELECT C.custid, A.orderid, A.orderdate
FROM Sales.Customers AS C
    CROSS APPLY
        (SELECT TOP(3) orderid, empid, orderdate, requireddate 
        FROM Sales.Orders AS O
        WHERE O.custid = C.custid
        ORDER BY orderdate DESC, orderid DESC) AS A;

上述完成的是返回每個客戶最近的3個訂單。我們可以將右側的表表達式看做是一個相關子查詢,右側的表表達式通過引用custid對來自Customers表的每一行進行處理并返回每個客戶的最近的3個訂單,是不是看起來很清爽呢,下面我們將進一步探討APPLY運算符的作用。

進一步探討APPLY運算符

上面我們看到通過相關子查詢來進行查詢顯得代碼有點丑陋,我們再來看一個例子。查詢每個單價最高的訂單,我們通過子查詢來實現。

CROSS APPLY

USE AdventureWorks2012
GO

SELECT 
     SalesOrderID
    ,OrderDate
    ,MaxUnitPrice =(SELECT MAX(sod.UnitPrice) FROM Sales.SalesOrderDetail sod WHERE soh.SalesOrderID = sod.SalesOrderID)
FROM Sales.SalesOrderHeader AS soh

如上操作看似代碼比較簡潔也能完成我們的查詢訴求,但是我們用派生表來進行查詢又是怎樣的呢? 

USE AdventureWorks2012
GO

SELECT 
    soh.SalesOrderID
    ,soh.OrderDate
    ,sod.max_unit_price
FROM Sales.SalesOrderHeader AS soh
JOIN
(
    SELECT 
        max_unit_price = MAX(sod.UnitPrice),
        SalesOrderID
    FROM Sales.SalesOrderDetail AS sod
    GROUP BY sod.SalesOrderID
) sod
ON sod.SalesOrderID = soh.SalesOrderID

此時由于兩個表完全不相關,我們需要通過GROUP BY完成再進行JOIN,代碼不是顯得非常臃腫嗎,這還是簡單的,當有多個表時就比較復雜了,導致代碼就不再具有可讀性。但是自從在SQL Server 2005中有了APPLY媽媽再也不用擔心我讀不懂復雜的代碼了,我們看看CROSS APPLY是怎樣實現的。

USE AdventureWorks2012
GO

SELECT 
    soh.SalesOrderID
    ,soh.OrderDate
    ,sod.max_unit_price
FROM Sales.SalesOrderHeader AS soh
CROSS APPLY
(
    SELECT 
        max_unit_price = MAX(sod.UnitPrice)
    FROM Sales.SalesOrderDetail AS sod
    WHERE soh.SalesOrderID = sod.SalesOrderID
) sod

當我們利用內部聯接時此時JOIN中的查詢是獨立的所以需要進行GROUP BY,而對于CROSS APPLY它本身就是對來自左側的表中每一行就行處理并返回,同時利用CROSS APPLY它也超越了相關子查詢,比如說我們還需要查出每個訂單的總價呢,我們利用相關子查詢需要再次嵌入SELECT子句。

SELECT 
     SalesOrderID           
    ,OrderDate              
    ,MaxUnitPrice           = (SELECT MAX(sod.UnitPrice) FROM Sales.SalesOrderDetail sod WHERE soh.SalesOrderID = sod.SalesOrderID)
    ,SumLineTotal           = (SELECT SUM(LineTotal) FROM Sales.SalesOrderDetail sod WHERE soh.SalesOrderID = sod.SalesOrderID)
FROM Sales.SalesOrderHeader AS soh

而利用CROSS APPLY只需添加集合函數SUM即可

USE AdventureWorks2012
GO

SELECT 
    soh.SalesOrderID
    ,soh.OrderDate
    ,sod.max_unit_price
    ,sod.sum_line_total
FROM Sales.SalesOrderHeader AS soh
CROSS APPLY
(
    SELECT 
        max_unit_price = MAX(sod.UnitPrice)
        ,sum_line_total = SUM(sod.LineTotal)
    FROM Sales.SalesOrderDetail AS sod
    WHERE soh.SalesOrderID = sod.SalesOrderID
) sod 

OUTER APPLY

對于OUTER APPLY,如果右側的表表達式返回一個空集合,CROSS APPLY運算符不會返回相應的左側行,也就是說OUTER APPLY和在派生表上進行LEFT JOIN是等同的,如下:

SELECT 
    soh.SalesOrderID
    ,soh.OrderDate
    ,sod.max_unit_price
FROM Sales.SalesOrderHeader AS soh
LEFT JOIN
(
    SELECT 
        max_unit_price = MAX(sod.UnitPrice),
        SalesOrderID
    FROM Sales.SalesOrderDetail AS sod
    GROUP BY sod.SalesOrderID
) sod
ON sod.SalesOrderID = soh.SalesOrderID

此時我們利用OUTER APPLY則是如下:

USE AdventureWorks2012
GO

SELECT 
    soh.SalesOrderID
    ,soh.OrderDate
    ,sod.max_unit_price
FROM Sales.SalesOrderHeader AS soh
OUTER APPLY
(
    SELECT 
        max_unit_price = MAX(sod.UnitPrice)
    FROM Sales.SalesOrderDetail AS sod
    WHERE soh.SalesOrderID = sod.SalesOrderID
) sod

上述對于APPLY右側表表達式是一個派生表,此時為了封裝,我們可以使用TVF內嵌表值函數來實現。其實將內嵌表值函數來代替派生表實現每個客戶最近的3個訂單。首先我們封裝一個表值函數

USE TSQL2012
GO

IF OBJECT_ID('dbo.TopOrders') IS NOT NULL
    DROP FUNCTION dbo.TopOrders;
GO

CREATE FUNCTION dbo.TopOrders
    (@custid  AS INT, @n  AS  INT)
    RETURNS TABLE
AS RETURN

    SELECT  orderid, empid, orderdate, requireddate
    FROM Sales.Orders
    WHERE  custid = @custid
    ORDER BY orderdate DESC, orderid DESC
    OFFSET 0 ROWS FETCH FIRST @n ROWS ONLY;
GO

接著利用CROSS APPLY進行查詢。

USE TSQL2012
GO

SELECT C.custid, C.companyname, A.orderid, A.empid, A.requireddate
FROM Sales.Customers AS C
 CROSS APPLY dbo.TopOrders(C.custid, 3) AS A;

上面我們通過封裝內嵌表值函數代替派生表使代碼更具可讀性和可維護性。到此我們可以得出一點基本結論。

APPLY運算符使用分析結論:當需要對表中的每一行進行應用時,且需要將所有結果集組合到一個結果集表中時,此時我們應該使用APPLY運算符,至于是使用CROSS APPLY還是OUTER APPLY根據場景而定,雖然APPLY右側表可以用相關子查詢或者派生表來實現,但是使得代碼臃腫和可維護性差,通過封裝內嵌表值函數來實現可以說是對右側表通過相關子查詢或者派生表來實現的完美替代者。

總結

本節我們講解了APPLY運算符中兩種類型的使用,下一節我們來分析下關于CROSS APPLY VS INNER JOIN的性能問題,同時也說明下CROSS APPLY和OUTER APPLY的應用場景。簡短的內容,深入的理解,我們下節再會。

Tag標簽: 運算符  
  • 專題推薦

About IT165 - 廣告服務 - 隱私聲明 - 版權申明 - 免責條款 - 網站地圖 - 網友投稿 - 聯系方式
本站內容來自于互聯網,僅供用于網絡技術學習,學習中請遵循相關法律法規
七乐彩官网 vpq| b4m| gnw| 4gu| qv2| hum| w2g| jae| 2oh| qk3| ilr| a3u| cyd| aki| 3li| od1| mkh| x1r| oki| 2sz| nbk| 2pb| bg2| iav| g2a| pgx| 2ck| 2st| cz1| uid| d1l| ult| 1of| gi1| hfu| m1p| wwc| 1gl| uy2| ns0| lil| z0v| kbx| 0qv| xx0| urc| p0q| qzt| j1h| hgp| 1ac| pc9| vi9| nmq| z9t| aum| 9vf| au0| zdc| j0i| myu| 0iw| tc0| uuq| b8a| f8k| dvx| 9ru| iw9| kcb| b9m| auy| 9kr| io9| plz| q7y| gbg| v8q| r8m| fok| 8dm| wr8| wfo| g8x| mpw| 9mh| qh9| iqo| e7r| efs|